作者:	Andreas Rumpf
版本:	|nimversion|

"Look at you, hacker. A pathetic creature of meat and bone, panting and sweating as you run through my corridors. How can you challenge a perfect, immortal machine?"

Introduction

本文介绍了 Nim 编译器在不同平台上的使用。它并不是 Nim 编程语言的定义（如果想了解定义请看这篇 指南 ）。

Nim 是自由软件，使用 MIT 协议授权。

编译器的使用

命令行参数

基础命令行参数：

用法：

nim 命令 [选项] [项目文件] [程序参数]

Command:

compile, c	用默认（C）代码生成器编译项目
doc	为输入的文件生成文档
doc2	为所有项目生成文档

程序参数：

程序参数会在程序运行时传递进去（如果启用了 --run 选项的话）

选项：

-p, --path:PATH	添加路径到搜索路径中
-d, --define:SYMBOL	定义一个条件标识符
-u, --undef:SYMBOL	取消定义一个条件标识符
-f, --forceBuild	强制重建所有模块
--stackTrace:on|off	开关堆栈跟踪
--lineTrace:on|off	开关轨迹追踪
--threads:on|off	开关多线程支持
-x, --checks:on|off	开关所有运行时检查
--objChecks:on|off	开关对象转换检查
--fieldChecks:on|off	开关实例的变种字段检查
--rangeChecks:on|off	开关范围检查
--boundChecks:on|off	开关边界检查
--overflowChecks:on|off	开关整型的 溢出/下溢 检查
-a, --assertions:on|off	开关断言
--floatChecks:on|off	开关所有浮点（NaN/Inf）检查
--nanChecks:on|off	开关 NaN 检查
--infChecks:on|off	开关 Inf 检查
--deadCodeElim:on|off	开关所有程序的死代码消除
--opt:none|speed|size	优化 无|运行速度|文件体积
--debugger:native|endb	使用 原生调试器（gdb）|ENDB（实验性的）
--app:console|gui|lib|staticlib	生成一个 命令行程序|图形界面程序|DLL|静态库
-r, --run	使用给予的参数运行编译的程序
--advanced	显示高级命令行参数
-h, --help	显示本帮助

Note, single letter options that take an argument require a colon. E.g. -p:PATH.

---

高级命令行参数：

高级命令:

compileToC, cc	编译程序到C
compileToCpp, cpp	编译程序到C++
compileToOC, objc	编译程序到Objective-C
js	编译程序到Javascript
rst2html	将reStructuredText文件转换到HTML
rst2tex	将reStructuredText文件转换到TeX
jsondoc	将文档解压到JSON文件
buildIndex	为整个文档构建索引
run	运行程序 (使用简易C后端; 超多bug!)
genDepend	生成一个包含模块依赖图的DOT文件
dump	转储所有定义的条件和搜索路径
check	检查程序的语法和语义
idetools	对IDE的编译器支持: 可能的选项: --track:FILE,LINE,COL 追踪文件/光标位置 --trackDirty:DIRTY_FILE,ORIG_FILE,LINE,COL 追踪目前还没有保存到磁盘的文件 --suggest 建议当前位置的所有可能的symbol --def 列出当前位置所有可能的定义 --context 列出可能的上下文调用 --usages 列出当前位置symbol所有的用法 --eval 计算一个表达式 serve 以编译服务模式运行 (CAAS) --server.type:TYPE 服务类型：stdin或tcp --server.port:PORT TCP端口, 默认6000 --server.address:HOST 绑定到该地址, 默认 ""

高级选项:

-o, --out:FILE	设置输出文件名
--stdout	输出到stdout
--listFullPaths	用信息列出完整路径
-w, --warnings:on|off	开/关所有警告
--warning[X]:on|off	开/关特定警告X
--hints:on|off	开/关所有提示
--hint[X]:on|off	开/关特定提示X
--lib:PATH	设置系统库文件路径
--import:PATH	添加一个"自动导入"的模块
--include:PATH	添加一个"自动包含"的模块
--nimcache:PATH	设置缓存路径
--header:FILE	编译器应当生成头文件(文件路径可选)
-c, --compileOnly	仅编译; 不进行汇编和链接
--noLinking	编译但不链接
--noMain	不要生成一个Main过程
--genScript	生成一个编译脚本 (在'nimcache' 子文件夹以'compile_$project$scriptext'命名)
--os:SYMBOL	设定目标操作系统(交叉编译)
--cpu:SYMBOL	设定目标处理器(交叉编译)
--debuginfo	启用调试信息输出
-t, --passC:OPTION	传递选项给 C 编译器
-l, --passL:OPTION	传递选项给 链接器
--cincludes:DIR	修改头文件搜索路径
--clibdir:DIR	修改库文件搜索路径
--clib:LIBNAME	链接一个附加的库 (你应该避免使用特定于平台的扩展)
--genMapping	生成一个包含 (Nim, mangled)标识符对的映射文件
--project	为整个项目生成文档(doc2)
--docSeeSrcUrl:url	为doc和doc2命令激活 'see source' 功能 (see doc.item.seesrc in config/nimdoc.cfg)
--lineDir:on|off	generation of #line directive on|off
--embedsrc	将源代码以注释嵌入到所生成的文件中
--threadanalysis:on|off	开/关线程分析
--tlsEmulation:on|off	开/关线程本地存储模拟
--taintMode:on|off	开/关污染模式
--implicitStatic:on|off	开/关隐含编译耗时评判
--patterns:on|off	turn pattern matching on|off
--skipCfg	do not read the general configuration file
--skipUserCfg	do not read the user's configuration file
--skipParentCfg	do not read the parent dirs' configuration files
--skipProjCfg	do not read the project's configuration file
--gc:refc|v2|markAndSweep|boehm|none	select the GC to use; default is 'refc'
--index:on|off	turn index file generation on|off
--putenv:key=value	设置一个环境变量
--NimblePath:PATH	add a path for Nimble support
--noNimblePath	deactivate the Nimble path
--excludePath:PATH	exclude a path from the list of search paths
--dynlibOverride:SYMBOL	marks SYMBOL so that dynlib:SYMBOL has no effect and can be statically linked instead; symbol matching is fuzzy so that --dynlibOverride:lua matches dynlib: "liblua.so.3"
--listCmd	list the commands used to execute external programs
--parallelBuild:0|1|...	perform a parallel build value = number of processors (0 for auto-detect)
--verbosity:0|1|2|3	设置Nim的"啰嗦"程度 (默认值是1)
--experimental	启用实验性语言特性
-v, --version	显示详细的版本信息

List of warnings

Each warning can be activated individually with --warning[NAME]:on|off or in a push pragma.

Name	Description
CannotOpenFile	Some file not essential for the compiler's working could not be opened.
OctalEscape	The code contains an unsupported octal sequence.
Deprecated	The code uses a deprecated symbol.
ConfigDeprecated	The project makes use of a deprecated config file.
SmallLshouldNotBeUsed	The letter 'l' should not be used as an identifier.
EachIdentIsTuple	The code contains a confusing var declaration.
ShadowIdent	A local variable shadows another local variable of an outer scope.
User	Some user defined warning.

Verbosity levels

Level	Description
0	Minimal output level for the compiler.
1	Displays compilation of all the compiled files, including those imported by other modules or through the compile pragma. This is the default level.
2	Displays compilation statistics, enumerates the dynamic libraries that will be loaded by the final binary and dumps to standard output the result of applying a filter to the source code if any filter was used during compilation.
3	In addition to the previous levels dumps a debug stack trace for compiler developers.

Compile time symbols

Through the -d:x or --define:x switch you can define compile time symbols for conditional compilation. The defined switches can be checked in source code with the when statement and defined proc. The typical use of this switch is to enable builds in release mode (-d:release) where certain safety checks are omitted for better performance. Another common use is the -d:ssl switch to activate SSL sockets.

Configuration files

Note: The project file name is the name of the .nim file that is passed as a command line argument to the compiler.

The nim executable processes configuration files in the following directories (in this order; later files overwrite previous settings):

1. $nim/config/nim.cfg, /etc/nim.cfg (UNIX) or %NIMROD%/config/nim.cfg (Windows). This file can be skipped with the --skipCfg command line option.
2. /home/$user/.config/nim.cfg (UNIX) or %APPDATA%/nim.cfg (Windows). This file can be skipped with the --skipUserCfg command line option.
3. $parentDir/nim.cfg where $parentDir stands for any parent directory of the project file's path. These files can be skipped with the --skipParentCfg command line option.
4. $projectDir/nim.cfg where $projectDir stands for the project file's path. This file can be skipped with the --skipProjCfg command line option.
5. A project can also have a project specific configuration file named $project.nim.cfg that resides in the same directory as $project.nim. This file can be skipped with the --skipProjCfg command line option.

Command line settings have priority over configuration file settings.

The default build of a project is a debug build. To compile a release build define the release symbol:

nim c -d:release myproject.nim

Search path handling

Nim has the concept of a global search path (PATH) that is queried to determine where to find imported modules or include files. If multiple files are found an ambiguity error is produced.

nim dump shows the contents of the PATH.

However before the PATH is used the current directory is checked for the file's existence. So if PATH contains $lib and $lib/bar and the directory structure looks like this:

$lib/x.nim
$lib/bar/x.nim
foo/x.nim
foo/main.nim
other.nim

And main imports x, foo/x is imported. If other imports x then both $lib/x.nim and $lib/bar/x.nim match and so the compiler should reject it. Currently however this check is not implemented and instead the first matching file is used.

Generated C code directory

The generated files that Nim produces all go into a subdirectory called nimcache in your project directory. This makes it easy to delete all generated files. Files generated in this directory follow a naming logic which you can read about in the Nim Backend Integration document.

However, the generated C code is not platform independent. C code generated for Linux does not compile on Windows, for instance. The comment on top of the C file lists the OS, CPU and CC the file has been compiled for.

Compilation cache

Warning: The compilation cache is still highly experimental!

The nimcache directory may also contain so called rod or symbol files. These files are pre-compiled modules that are used by the compiler to perform incremental compilation. This means that only modules that have changed since the last compilation (or the modules depending on them etc.) are re-compiled. However, per default no symbol files are generated; use the --symbolFiles:on command line switch to activate them.

Unfortunately due to technical reasons the --symbolFiles:on needs to aggregate some generated C code. This means that the resulting executable might contain some cruft even when dead code elimination is turned on. So the final release build should be done with --symbolFiles:off.

Due to the aggregation of C code it is also recommended that each project resides in its own directory so that the generated nimcache directory is not shared between different projects.

交叉编译

一个交叉编译的例子：

nim c --cpu:i386 --os:linux --compile_only --gen_script myproject.nim

然后将 C 源码和编译脚本 compile_myproject.sh 移动到你的 Linux i386 机器上，运行脚本。

另一种方式是调用交叉编译工具链：

nim c --cpu:arm --os:linux myproject.nim

Nim 编译器会读取配置文件中名字为 $cpu.$os.$cc 的配置（比如 arm.linux.gcc）来调用对应的 C 编译器。例如 ARM 的配置是这样的：

arm.linux.gcc.path = "/usr/bin" arm.linux.gcc.exe = "arm-linux-gcc" arm.linux.gcc.linkerexe = "arm-linux-gcc"

DLL generation

Nim supports the generation of DLLs. However, there must be only one instance of the GC per process/address space. This instance is contained in nimrtl.dll. This means that every generated Nim DLL depends on nimrtl.dll. To generate the "nimrtl.dll" file, use the command:

nim c -d:release lib/nimrtl.nim

To link against nimrtl.dll use the command:

nim c -d:useNimRtl myprog.nim

Note: Currently the creation of nimrtl.dll with thread support has never been tested and is unlikely to work!

Additional compilation switches

The standard library supports a growing number of useX conditional defines affecting how some features are implemented. This section tries to give a complete list.

Define	Effect
release	Turns off runtime checks and turns on the optimizer.
useWinAnsi	Modules like os and osproc use the Ansi versions of the Windows API. The default build uses the Unicode version.
useFork	Makes osproc use fork instead of posix_spawn.
useNimRtl	Compile and link against nimrtl.dll.
useMalloc	Makes Nim use C's malloc instead of Nim's own memory manager. This only works with gc:none.
useRealtimeGC	Enables support of Nim's GC for soft realtime systems. See the documentation of the gc for further information.
nodejs	The JS target is actually node.js.
ssl	Enables OpenSSL support for the sockets module.
memProfiler	Enables memory profiling for the native GC.
uClibc	Use uClibc instead of libc. (Relevant for Unix-like OSes)

Additional Features

This section describes Nim's additional features that are not listed in the Nim manual. Some of the features here only make sense for the C code generator and are subject to change.

NoDecl pragma

The noDecl pragma can be applied to almost any symbol (variable, proc, type, etc.) and is sometimes useful for interoperability with C: It tells Nim that it should not generate a declaration for the symbol in the C code. For example:

var
  EACCES {.importc, noDecl.}: cint # pretend EACCES was a variable, as
                                   # Nim does not know its value

However, the header pragma is often the better alternative.

Note: This will not work for the LLVM backend.

Header pragma

The header pragma is very similar to the noDecl pragma: It can be applied to almost any symbol and specifies that it should not be declared and instead the generated code should contain an #include:

type
  PFile {.importc: "FILE*", header: "<stdio.h>".} = distinct pointer
    # import C's FILE* type; Nim will treat it as a new pointer type

The header pragma always expects a string constant. The string contant contains the header file: As usual for C, a system header file is enclosed in angle brackets: <>. If no angle brackets are given, Nim encloses the header file in "" in the generated C code.

Note: This will not work for the LLVM backend.

IncompleteStruct pragma

The incompleteStruct pragma tells the compiler to not use the underlying C struct in a sizeof expression:

type
  DIR* {.importc: "DIR", header: "<dirent.h>",
         final, pure, incompleteStruct.} = object

Compile pragma

The compile pragma can be used to compile and link a C/C++ source file with the project:

{.compile: "myfile.cpp".}

Note: Nim computes a CRC checksum and only recompiles the file if it has changed. You can use the -f command line option to force recompilation of the file.

Link pragma

The link pragma can be used to link an additional file with the project:

{.link: "myfile.o".}

PassC pragma

The passC pragma can be used to pass additional parameters to the C compiler like you would using the commandline switch --passC:

{.passC: "-Wall -Werror".}

Note that you can use gorge from the system module to embed parameters from an external command at compile time:

{.passC: gorge("pkg-config --cflags sdl").}

PassL pragma

The passL pragma can be used to pass additional parameters to the linker like you would using the commandline switch --passL:

{.passL: "-lSDLmain -lSDL".}

Note that you can use gorge from the system module to embed parameters from an external command at compile time:

{.passL: gorge("pkg-config --libs sdl").}

Emit pragma

The emit pragma can be used to directly affect the output of the compiler's code generator. So it makes your code unportable to other code generators/backends. Its usage is highly discouraged! However, it can be extremely useful for interfacing with C++ or Objective C code.

Example:

{.emit: """
static int cvariable = 420;
""".}

{.push stackTrace:off.}
proc embedsC() =
  var nimVar = 89
  # use backticks to access Nim symbols within an emit section:
  {.emit: """fprintf(stdout, "%d\n", cvariable + (int)`nimVar`);""".}
{.pop.}

embedsC()

As can be seen from the example, to Nim symbols can be referred via backticks. Use two backticks to produce a single verbatim backtick.

ImportCpp pragma

Note: c2nim can parse a large subset of C++ and knows about the importcpp pragma pattern language. It is not necessary to know all the details described here.

Similar to the importc pragma for C, the importcpp pragma can be used to import C++ methods or C++ symbols in general. The generated code then uses the C++ method calling syntax: obj->method(arg). In combination with the header and emit pragmas this allows sloppy interfacing with libraries written in C++:

# Horrible example of how to interface with a C++ engine ... ;-)

{.link: "/usr/lib/libIrrlicht.so".}

{.emit: """
using namespace irr;
using namespace core;
using namespace scene;
using namespace video;
using namespace io;
using namespace gui;
""".}

const
  irr = "<irrlicht/irrlicht.h>"

type
  IrrlichtDeviceObj {.final, header: irr,
                      importcpp: "IrrlichtDevice".} = object
  IrrlichtDevice = ptr IrrlichtDeviceObj

proc createDevice(): IrrlichtDevice {.
  header: irr, importcpp: "createDevice(@)".}
proc run(device: IrrlichtDevice): bool {.
  header: irr, importcpp: "#.run(@)".}

The compiler needs to be told to generate C++ (command cpp) for this to work. The conditional symbol cpp is defined when the compiler emits C++ code.

Namespaces

The sloppy interfacing example uses .emit to produce using namespace declarations. It is usually much better to instead refer to the imported name via the namespace::identifier notation:

type
  IrrlichtDeviceObj {.final, header: irr,
                      importcpp: "irr::IrrlichtDevice".} = object

Importcpp for enums

When importcpp is applied to an enum type the numerical enum values are annotated with the C++ enum type, like in this example: ((TheCppEnum)(3)). (This turned out to be the simplest way to implement it.)

Importcpp for procs

Note that the importcpp variant for procs uses a somewhat cryptic pattern language for maximum flexibility:

• A hash # symbol is replaced by the first or next argument.
• A dot following the hash #. indicates that the call should use C++'s dot or arrow notation.
• An at symbol @ is replaced by the remaining arguments, separated by commas.

For example:

proc cppMethod(this: CppObj, a, b, c: cint) {.importcpp: "#.CppMethod(@)".}
var x: ptr CppObj
cppMethod(x[], 1, 2, 3)

Produces:

x->CppMethod(1, 2, 3)

As a special rule to keep backwards compatibility with older versions of the importcpp pragma, if there is no special pattern character (any of # ' @) at all, C++'s dot or arrow notation is assumed, so the above example can also be written as:

proc cppMethod(this: CppObj, a, b, c: cint) {.importcpp: "CppMethod".}

Note that the pattern language naturally also covers C++'s operator overloading capabilities:

proc vectorAddition(a, b: Vec3): Vec3 {.importcpp: "# + #".}
proc dictLookup(a: Dict, k: Key): Value {.importcpp: "#[#]".}

• An apostrophe ' followed by an integer i in the range 0..9 is replaced by the i'th parameter type. The 0th position is the result type. This can be used to pass types to C++ function templates. Between the ' and the digit an asterisk can be used to get to the base type of the type. (So it "takes away a star" from the type; T* becomes T.) Two stars can be used to get to the element type of the element type etc.

For example:

type Input {.importcpp: "System::Input".} = object
proc getSubsystem*[T](): ptr T {.importcpp: "SystemManager::getSubsystem<'*0>()".}

let x: ptr Input = getSubsystem[Input]()

Produces:

x = SystemManager::getSubsystem<System::Input>()

• #@ is a special case to support a cnew operation. It is required so that the call expression is inlined directly, without going through a temporary location. This is only required to circumvent a limitation of the current code generator.

For example C++'s new operator can be "imported" like this:

proc cnew*[T](x: T): ptr T {.importcpp: "(new '*0#@)", nodecl.}

# constructor of 'Foo':
proc constructFoo(a, b: cint): Foo {.importcpp: "Foo(@)".}

let x = cnew constructFoo(3, 4)

Produces:

x = new Foo(3, 4)

However, depending on the use case new Foo can also be wrapped like this instead:

proc newFoo(a, b: cint): ptr Foo {.importcpp: "new Foo(@)".}

let x = newFoo(3, 4)

Wrapping destructors

Since Nim generates C++ directly, any destructor is called implicitly by the C++ compiler at the scope exits. This means that often one can get away with not wrapping the destructor at all! However when it needs to be invoked explicitly, it needs to be wrapped. But the pattern language already provides everything that is required for that:

proc destroyFoo(this: var Foo) {.importcpp: "#.~Foo()".}

Importcpp for objects

Generic importcpp'ed objects are mapped to C++ templates. This means that you can import C++'s templates rather easily without the need for a pattern language for object types:

type
  StdMap {.importcpp: "std::map", header: "<map>".} [K, V] = object
proc `[]=`[K, V](this: var StdMap[K, V]; key: K; val: V) {.
  importcpp: "#[#] = #", header: "<map>".}

var x: StdMap[cint, cdouble]
x[6] = 91.4

Produces:

std::map<int, double> x;
x[6] = 91.4;

ImportObjC pragma

Similar to the importc pragma for C, the importobjc pragma can be used to import Objective C methods. The generated code then uses the Objective C method calling syntax: [obj method param1: arg]. In addition with the header and emit pragmas this allows sloppy interfacing with libraries written in Objective C:

# horrible example of how to interface with GNUStep ...

{.passL: "-lobjc".}
{.emit: """
#include <objc/Object.h>
@interface Greeter:Object
{
}

- (void)greet:(long)x y:(long)dummy;
@end

#include <stdio.h>
@implementation Greeter

- (void)greet:(long)x y:(long)dummy
{
        printf("Hello, World!\n");
}
@end

#include <stdlib.h>
""".}

type
  Id {.importc: "id", header: "<objc/Object.h>", final.} = distinct int

proc newGreeter: Id {.importobjc: "Greeter new", nodecl.}
proc greet(self: Id, x, y: int) {.importobjc: "greet", nodecl.}
proc free(self: Id) {.importobjc: "free", nodecl.}

var g = newGreeter()
g.greet(12, 34)
g.free()

The compiler needs to be told to generate Objective C (command objc) for this to work. The conditional symbol objc is defined when the compiler emits Objective C code.

CodegenDecl pragma

The codegenDecl pragma can be used to directly influence Nim's code generator. It receives a format string that determines how the variable or proc is declared in the generated code:

var
  a {.codegenDecl: "$# progmem $#".}: int

proc myinterrupt() {.codegenDecl: "__interrupt $# $#$#".} =
  echo "realistic interrupt handler"

InjectStmt pragma

The injectStmt pragma can be used to inject a statement before every other statement in the current module. It is only supposed to be used for debugging:

{.injectStmt: gcInvariants().}

# ... complex code here that produces crashes ...

LineDir option

The lineDir option can be turned on or off. If turned on the generated C code contains #line directives. This may be helpful for debugging with GDB.

StackTrace option

If the stackTrace option is turned on, the generated C contains code to ensure that proper stack traces are given if the program crashes or an uncaught exception is raised.

LineTrace option

The lineTrace option implies the stackTrace option. If turned on, the generated C contains code to ensure that proper stack traces with line number information are given if the program crashes or an uncaught exception is raised.

Debugger option

The debugger option enables or disables the Embedded Nim Debugger. See the documentation of endb for further information.

Breakpoint pragma

The breakpoint pragma was specially added for the sake of debugging with ENDB. See the documentation of endb for further information.

Volatile pragma

The volatile pragma is for variables only. It declares the variable as volatile, whatever that means in C/C++ (its semantics are not well defined in C/C++).

Note: This pragma will not exist for the LLVM backend.

DynlibOverride

By default Nim's dynlib pragma causes the compiler to generate GetProcAddress (or their Unix counterparts) calls to bind to a DLL. With the dynlibOverride command line switch this can be prevented and then via --passL the static library can be linked against. For instance, to link statically against Lua this command might work on Linux:

nim c --dynlibOverride:lua --passL:liblua.lib program.nim

Backend language options

The typical compiler usage involves using the compile or c command to transform a .nim file into one or more .c files which are then compiled with the platform's C compiler into a static binary. However there are other commands to compile to C++, Objective-C or Javascript. More details can be read in the Nim Backend Integration document.

Nim documentation tools

Nim provides the doc and doc2 commands to generate HTML documentation from .nim source files. Only exported symbols will appear in the output. For more details see the docgen documentation.

Nim idetools integration

Nim provides language integration with external IDEs through the idetools command. See the documentation of idetools for further information.

Nim interactive mode

The Nim compiler supports an interactive mode. This is also known as a REPL (read eval print loop). If Nim has been built with the -d:useGnuReadline switch, it uses the GNU readline library for terminal input management. To start Nim in interactive mode use the command nim i. To quit use the quit() command. To determine whether an input line is an incomplete statement to be continued these rules are used:

1. The line ends with [-+*/\\<>!\?\|%&$@~,;:=#^]\s*$ (operator symbol followed by optional whitespace).
2. The line starts with a space (indentation).
3. The line is within a triple quoted string literal. However, the detection does not work if the line contains more than one """.

Nim for embedded systems

The standard library can be avoided to a point where C code generation for 16bit micro controllers is feasible. Use the standalone target (--os:standalone) for a bare bones standard library that lacks any OS features.

To make the compiler output code for a 16bit target use the --cpu:avr target.

For example, to generate code for an AVR processor use this command:

nim c --cpu:avr --os:standalone --deadCodeElim:on --genScript x.nim

For the standalone target one needs to provide a file panicoverride.nim. See tests/manyloc/standalone/panicoverride.nim for an example implementation.

Nim for realtime systems

See the documentation of Nim's soft realtime GC for further information.

Debugging with Nim

Nim comes with its own Embedded Nim Debugger. See the documentation of endb for further information.

Optimizing for Nim

Nim has no separate optimizer, but the C code that is produced is very efficient. Most C compilers have excellent optimizers, so usually it is not needed to optimize one's code. Nim has been designed to encourage efficient code: The most readable code in Nim is often the most efficient too.

However, sometimes one has to optimize. Do it in the following order:

1. switch off the embedded debugger (it is slow!)
2. turn on the optimizer and turn off runtime checks
3. profile your code to find where the bottlenecks are
4. try to find a better algorithm
5. do low-level optimizations

This section can only help you with the last item.

Optimizing string handling

String assignments are sometimes expensive in Nim: They are required to copy the whole string. However, the compiler is often smart enough to not copy strings. Due to the argument passing semantics, strings are never copied when passed to subroutines. The compiler does not copy strings that are a result from a procedure call, because the callee returns a new string anyway. Thus it is efficient to do:

var s = procA() # assignment will not copy the string; procA allocates a new
                # string already

However it is not efficient to do:

var s = varA    # assignment has to copy the whole string into a new buffer!

For let symbols a copy is not always necessary:

let s = varA    # may only copy a pointer if it safe to do so

If you know what you're doing, you can also mark single string (or sequence) objects as shallow:

var s = "abc"
shallow(s) # mark 's' as shallow string
var x = s  # now might not copy the string!

Usage of shallow is always safe once you know the string won't be modified anymore, similar to Ruby's freeze.

The compiler optimizes string case statements: A hashing scheme is used for them if several different string constants are used. So code like this is reasonably efficient:

case normalize(k.key)
of "name": c.name = v
of "displayname": c.displayName = v
of "version": c.version = v
of "os": c.oses = split(v, {';'})
of "cpu": c.cpus = split(v, {';'})
of "authors": c.authors = split(v, {';'})
of "description": c.description = v
of "app":
  case normalize(v)
  of "console": c.app = appConsole
  of "gui": c.app = appGUI
  else: quit(errorStr(p, "expected: console or gui"))
of "license": c.license = UnixToNativePath(k.value)
else: quit(errorStr(p, "unknown variable: " & k.key))